Parkeersensor luxe

// Parkeersensor luxe
// Net als de gewone parkeersensor, maar nu zie je de afstand ook op het OLED-scherm.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG_PIN = 9;     // Trig van de HC-SR04 op pin 9
const int ECHO_PIN = 10;    // Echo van de HC-SR04 op pin 10
const int ZOEMER_PIN = 8;   // S van de zoemer op pin 8

Adafruit_SSD1306 scherm(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

// Meet de afstand in centimeters
long meetAfstand() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long tijd = pulseIn(ECHO_PIN, HIGH, 30000);
  if (tijd == 0) return 999;   // Geen echo: niets in de buurt
  return tijd / 58;
}

// Zet de afstand groot op het scherm, met een balkje eronder
void toonAfstand(long afstand) {
  scherm.clearDisplay();
  scherm.setTextSize(2);
  scherm.setCursor(0, 0);
  if (afstand >= 999) {
    scherm.print(F("---"));
  } else {
    scherm.print(afstand);
    scherm.print(F(" cm"));
  }
  // Balkje: hoe dichterbij, hoe langer
  int lengte = map(constrain(afstand, 0, 100), 0, 100, 128, 0);
  scherm.fillRect(0, 24, lengte, 8, SSD1306_WHITE);
  scherm.display();
}

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(ZOEMER_PIN, OUTPUT);
  scherm.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  scherm.setTextColor(SSD1306_WHITE);
}

void loop() {
  long afstand = meetAfstand();
  toonAfstand(afstand);

  if (afstand < 5) {
    digitalWrite(ZOEMER_PIN, HIGH);   // Heel dichtbij: één lange toon
    delay(100);
  } else if (afstand < 50) {
    digitalWrite(ZOEMER_PIN, HIGH);   // Korte piep
    delay(50);
    digitalWrite(ZOEMER_PIN, LOW);
    delay(afstand * 10);              // Dichterbij = sneller piepen
  } else {
    digitalWrite(ZOEMER_PIN, LOW);
    delay(100);
  }
}