Slimme ventilator

// Slimme ventilator (thermostaat)
// Wordt het te warm? Dan schakelt het relais aan, bijvoorbeeld voor een ventilator.
// Op het scherm zie je de temperatuur en of de ventilator aan staat.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT van de DHT11 op pin 2
const int RELAIS_PIN = 7;     // S van het relais op pin 7
const float AAN_BOVEN = 25.0; // Boven deze temperatuur gaat de ventilator aan
const float UIT_ONDER = 24.0; // Onder deze temperatuur gaat hij weer uit

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 scherm(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool ventilatorAan = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELAIS_PIN, OUTPUT);
  digitalWrite(RELAIS_PIN, LOW);   // Begin met het relais uit
  dht.begin();
  scherm.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  scherm.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperatuur = dht.readTemperature();

  if (!isnan(temperatuur)) {
    // Twee grenzen, zodat het relais niet steeds aan en uit klikt
    if (temperatuur > AAN_BOVEN) ventilatorAan = true;
    if (temperatuur < UIT_ONDER) ventilatorAan = false;
    digitalWrite(RELAIS_PIN, ventilatorAan ? HIGH : LOW);
  }

  scherm.clearDisplay();
  scherm.setTextSize(2);
  scherm.setCursor(0, 0);
  if (isnan(temperatuur)) {
    scherm.print(F("DHT11 ?"));
  } else {
    scherm.print(temperatuur, 1);
    scherm.print((char)247);
    scherm.print(F("C"));
  }
  scherm.setTextSize(1);
  scherm.setCursor(0, 22);
  scherm.print(ventilatorAan ? F("Ventilator: AAN") : F("Ventilator: uit"));
  scherm.display();

  Serial.print(F("Temperatuur: "));
  Serial.print(temperatuur);
  Serial.println(ventilatorAan ? F(" C  -> AAN") : F(" C  -> uit"));

  delay(2000);
}