PN532 RFID NFC Module

#include <Wire.h>
#include <Adafruit_PN532.h>

// Arduino Uno pins used by this example:
// IRQ  -> D2
// RSTO -> D3
Adafruit_PN532 nfc(2, 3);

void setup() {
  Serial.begin(115200);
  while (!Serial) {
    ;
  }

  Serial.println("PN532 NFC reader starting...");

  nfc.begin();

  uint32_t versiondata = nfc.getFirmwareVersion();
  if (!versiondata) {
    Serial.println("Didn't find PN532 board");
    while (1) {
      delay(10);
    }
  }

  Serial.print("Found PN532 chip, firmware version: ");
  Serial.print((versiondata >> 24) & 0xFF, HEX);
  Serial.print('.');
  Serial.println((versiondata >> 16) & 0xFF, HEX);

  nfc.SAMConfig();
  Serial.println("Waiting for an ISO14443A card/tag...");
}

void loop() {
  uint8_t uid[7];
  uint8_t uidLength;

  bool success = nfc.readPassiveTargetID(PN532_MIFARE_ISO14443A, uid, &uidLength, 1000);
  if (success) {
    Serial.print("Found tag UID: ");
    for (uint8_t i = 0; i < uidLength; i++) {
      if (uid[i] < 0x10) Serial.print('0');
      Serial.print(uid[i], HEX);
      if (i < uidLength - 1) Serial.print(':');
    }
    Serial.println();
    delay(1000);
  }
}