Smarter Ventilator

// Smarter Ventilator (Thermostat)
// Wird es zu warm? Dann schaltet das Relais ein, zum Beispiel für einen Ventilator.
// Auf dem Bildschirm siehst du die Temperatur und ob der Ventilator an ist.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT des DHT11 an pin 2
const int RELAIS_PIN = 7;     // S des Relais an pin 7
const float AN_UEBER = 25.0; // Über dieser Temperatur geht der Ventilator an
const float AUS_UNTER = 24.0; // Unter dieser Temperatur geht er wieder aus

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 bildschirm(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool ventilatorAn = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELAIS_PIN, OUTPUT);
  digitalWrite(RELAIS_PIN, LOW);   // Starte mit dem Relais aus
  dht.begin();
  bildschirm.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  bildschirm.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperatur = dht.readTemperature();

  if (!isnan(temperatur)) {
    // Zwei Grenzen, damit das Relais nicht dauernd an und aus klickt
    if (temperatur > AN_UEBER) ventilatorAn = true;
    if (temperatur < AUS_UNTER) ventilatorAn = false;
    digitalWrite(RELAIS_PIN, ventilatorAn ? HIGH : LOW);
  }

  bildschirm.clearDisplay();
  bildschirm.setTextSize(2);
  bildschirm.setCursor(0, 0);
  if (isnan(temperatur)) {
    bildschirm.print(F("DHT11 ?"));
  } else {
    bildschirm.print(temperatur, 1);
    bildschirm.print((char)247);
    bildschirm.print(F("C"));
  }
  bildschirm.setTextSize(1);
  bildschirm.setCursor(0, 22);
  bildschirm.print(ventilatorAn ? F("Ventilator: AN") : F("Ventilator: aus"));
  bildschirm.display();

  Serial.print(F("Temperatur: "));
  Serial.print(temperatur);
  Serial.println(ventilatorAn ? F(" C  -> AN") : F(" C  -> aus"));

  delay(2000);
}