Sensor de aparcamiento deluxe

// Sensor de aparcamiento deluxe
// Como el sensor normal, pero ahora también ves la distancia en la pantalla OLED.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG_PIN = 9;     // Trig del HC-SR04 en pin 9
const int ECHO_PIN = 10;    // Echo del HC-SR04 en pin 10
const int ZUMBADOR_PIN = 8;   // S del zumbador en pin 8

Adafruit_SSD1306 pantalla(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

// Mide la distancia en centímetros
long medirDistancia() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long tiempo = pulseIn(ECHO_PIN, HIGH, 30000);
  if (tiempo == 0) return 999;   // Sin echo: nada cerca
  return tiempo / 58;
}

// Pone la distancia grande en la pantalla, con una barrita debajo
void mostrarDistancia(long distancia) {
  pantalla.clearDisplay();
  pantalla.setTextSize(2);
  pantalla.setCursor(0, 0);
  if (distancia >= 999) {
    pantalla.print(F("---"));
  } else {
    pantalla.print(distancia);
    pantalla.print(F(" cm"));
  }
  // Barrita: cuanto más cerca, más larga
  int largo = map(constrain(distancia, 0, 100), 0, 100, 128, 0);
  pantalla.fillRect(0, 24, largo, 8, SSD1306_WHITE);
  pantalla.display();
}

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(ZUMBADOR_PIN, OUTPUT);
  pantalla.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  pantalla.setTextColor(SSD1306_WHITE);
}

void loop() {
  long distancia = medirDistancia();
  mostrarDistancia(distancia);

  if (distancia < 5) {
    digitalWrite(ZUMBADOR_PIN, HIGH);   // Muy cerca: un tono largo
    delay(100);
  } else if (distancia < 50) {
    digitalWrite(ZUMBADOR_PIN, HIGH);   // Pitido corto
    delay(50);
    digitalWrite(ZUMBADOR_PIN, LOW);
    delay(distancia * 10);              // Más cerca = más pitidos
  } else {
    digitalWrite(ZUMBADOR_PIN, LOW);
    delay(100);
  }
}