Capteur de parking luxe

// Capteur de parking luxe
// Comme le capteur de parking normal, mais maintenant tu vois aussi la distance sur l’écran OLED.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG_PIN = 9;     // Trig du HC-SR04 sur la broche 9
const int ECHO_PIN = 10;    // Echo du HC-SR04 sur la broche 10
const int BUZZER_PIN = 8;   // S du buzzer sur la broche 8

Adafruit_SSD1306 ecran(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

// Mesure la distance en centimètres
long mesurerDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long temps = pulseIn(ECHO_PIN, HIGH, 30000);
  if (temps == 0) return 999;   // Pas d’écho : rien tout près
  return temps / 58;
}

// Met la distance en grand sur l’écran, avec une petite barre dessous
void afficherDistance(long distance) {
  ecran.clearDisplay();
  ecran.setTextSize(2);
  ecran.setCursor(0, 0);
  if (distance >= 999) {
    ecran.print(F("---"));
  } else {
    ecran.print(distance);
    ecran.print(F(" cm"));
  }
  // Petite barre : plus c’est près, plus elle est longue
  int longueur = map(constrain(distance, 0, 100), 0, 100, 128, 0);
  ecran.fillRect(0, 24, longueur, 8, SSD1306_WHITE);
  ecran.display();
}

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  ecran.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  ecran.setTextColor(SSD1306_WHITE);
}

void loop() {
  long distance = mesurerDistance();
  afficherDistance(distance);

  if (distance < 5) {
    digitalWrite(BUZZER_PIN, HIGH);   // Très près : un long son
    delay(100);
  } else if (distance < 50) {
    digitalWrite(BUZZER_PIN, HIGH);   // Petit bip court
    delay(50);
    digitalWrite(BUZZER_PIN, LOW);
    delay(distance * 10);              // Plus près = bips plus vite
  } else {
    digitalWrite(BUZZER_PIN, LOW);
    delay(100);
  }
}