Sensore di parcheggio

// Sensore di parcheggio
// Più ti avvicini al sensore, più il cicalino suona veloce. Proprio come in auto!

const int TRIG_PIN = 9;     // Trig del HC-SR04 sul pin 9
const int ECHO_PIN = 10;    // Echo del HC-SR04 sul pin 10
const int CICALINO_PIN = 8;   // S del cicalino sul pin 8

void setup() {
  Serial.begin(9600);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(CICALINO_PIN, OUTPUT);
}

// Misura la distanza in centimetri
long misuraDistanza() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);     // Manda un suono breve (che tu non senti)
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long tempo = pulseIn(ECHO_PIN, HIGH, 30000);  // Quanto tempo serve perché l'eco torni?
  if (tempo == 0) return 999;                   // Nessuna eco: niente vicino
  return tempo / 58;                            // Converti il tempo in centimetri
}

void loop() {
  long distanza = misuraDistanza();
  Serial.print(F("Distanza: "));
  Serial.print(distanza);
  Serial.println(F(" cm"));

  if (distanza < 5) {
    digitalWrite(CICALINO_PIN, HIGH);   // Molto vicino: un tono lungo
    delay(100);
  } else if (distanza < 50) {
    digitalWrite(CICALINO_PIN, HIGH);   // Bip breve
    delay(50);
    digitalWrite(CICALINO_PIN, LOW);
    delay(distanza * 10);              // Più vicino = pausa più corta = bip più rapidi
  } else {
    digitalWrite(CICALINO_PIN, LOW);    // Lontano: silenzio
    delay(100);
  }
}