Mini stazione meteo

// Mini stazione meteo
// Il DHT11 misura la temperatura e l'umidità dell'aria. Lo schermino OLED lo mostra.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;          // DAT del DHT11 è sul pin 2
DHT dht(DHT_PIN, DHT11);

Adafruit_SSD1306 schermo(128, 32, &Wire, -1);  // OLED da 128 x 32 pixel (SDA = A4, SCL = A5)

void setup() {
  Serial.begin(9600);
  dht.begin();
  if (!schermo.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // 0x3C è l'indirizzo dello schermo
    Serial.println(F("Schermo non trovato. Controlla i fili di SDA e SCL."));
    while (true);                                   // Stop: senza schermo non serve
  }
  schermo.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperatura = dht.readTemperature();  // In gradi Celsius
  float umidita = dht.readHumidity();           // In percentuale

  schermo.clearDisplay();
  schermo.setTextSize(2);
  schermo.setCursor(0, 0);

  if (isnan(temperatura) || isnan(umidita)) {   // La misura non riesce?
    schermo.setTextSize(1);
    schermo.print(F("DHT11 non trovato"));
  } else {
    schermo.print(temperatura, 1);
    schermo.print((char)247);                  // Il simbolo dei gradi
    schermo.println(F("C"));
    schermo.print(umidita, 0);
    schermo.print(F("% umid"));

    Serial.print(F("Temperatura: "));
    Serial.print(temperatura);
    Serial.print(F(" C  Umid: "));
    Serial.print(umidita);
    Serial.println(F(" %"));
  }

  schermo.display();   // Solo ora tutto appare davvero sullo schermo
  delay(2000);        // Il DHT11 può misurare solo ogni 2 secondi
}