Sensore di parcheggio deluxe

// Sensore di parcheggio deluxe
// Come il sensore di parcheggio normale, ma ora vedi la distanza anche sul display OLED.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG_PIN = 9;     // Trig del HC-SR04 sul pin 9
const int ECHO_PIN = 10;    // Echo del HC-SR04 sul pin 10
const int CICALINO_PIN = 8;   // S del cicalino sul pin 8

Adafruit_SSD1306 display(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

// Misura la distanza in centimetri
long misuraDistanza() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long tempo = pulseIn(ECHO_PIN, HIGH, 30000);
  if (tempo == 0) return 999;   // Nessun eco: niente vicino
  return tempo / 58;
}

// Mostra la distanza grande sul display, con una barretta sotto
void mostraDistanza(long distanza) {
  display.clearDisplay();
  display.setTextSize(2);
  display.setCursor(0, 0);
  if (distanza >= 999) {
    display.print(F("---"));
  } else {
    display.print(distanza);
    display.print(F(" cm"));
  }
  // Barretta: più vicino, più lunga
  int lunghezza = map(constrain(distanza, 0, 100), 0, 100, 128, 0);
  display.fillRect(0, 24, lunghezza, 8, SSD1306_WHITE);
  display.display();
}

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(CICALINO_PIN, OUTPUT);
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  long distanza = misuraDistanza();
  mostraDistanza(distanza);

  if (distanza < 5) {
    digitalWrite(CICALINO_PIN, HIGH);   // Molto vicino: un tono lungo
    delay(100);
  } else if (distanza < 50) {
    digitalWrite(CICALINO_PIN, HIGH);   // Bip breve
    delay(50);
    digitalWrite(CICALINO_PIN, LOW);
    delay(distanza * 10);              // Più vicino = bip più veloci
  } else {
    digitalWrite(CICALINO_PIN, LOW);
    delay(100);
  }
}