Ventilatore intelligente

// Ventilatore intelligente (termostato)
// Fa troppo caldo? Allora il relè si attiva, per esempio per una ventola.
// Sullo schermo vedi la temperatura e se la ventola è accesa.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT del DHT11 sul pin 2
const int RELE_PIN = 7;       // S del relè sul pin 7
const float ACCESO_SOPRA = 25.0; // Sopra questa temperatura la ventola si accende
const float SPENTO_SOTTO = 24.0; // Sotto questa temperatura si spegne di nuovo

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 schermo(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool ventilatoreAcceso = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELE_PIN, OUTPUT);
  digitalWrite(RELE_PIN, LOW);   // Inizia con il relè spento
  dht.begin();
  schermo.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  schermo.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperatura = dht.readTemperature();

  if (!isnan(temperatura)) {
    // Due limiti, così il relè non fa clic di continuo
    if (temperatura > ACCESO_SOPRA) ventilatoreAcceso = true;
    if (temperatura < SPENTO_SOTTO) ventilatoreAcceso = false;
    digitalWrite(RELE_PIN, ventilatoreAcceso ? HIGH : LOW);
  }

  schermo.clearDisplay();
  schermo.setTextSize(2);
  schermo.setCursor(0, 0);
  if (isnan(temperatura)) {
    schermo.print(F("DHT11 ?"));
  } else {
    schermo.print(temperatura, 1);
    schermo.print((char)247);
    schermo.print(F("C"));
  }
  schermo.setTextSize(1);
  schermo.setCursor(0, 22);
  schermo.print(ventilatoreAcceso ? F("Ventola: accesa") : F("Ventola: spenta"));
  schermo.display();

  Serial.print(F("Temperatura: "));
  Serial.print(temperatura);
  Serial.println(ventilatoreAcceso ? F(" C  -> accesa") : F(" C  -> spenta"));

  delay(2000);
}