Nachtlampje

// Nachtlampje
// Wordt het donker? Dan gaat de LED-ring zacht branden. Wordt het licht? Dan gaat hij uit.

#include <Adafruit_NeoPixel.h>

const int LICHT_PIN = A0;   // S van de lichtsensor op A0
const int RING_PIN = 6;     // DI van de LED-ring op pin 6
const int AANTAL_LEDS = 8;

// Bij deze waarde vinden we het "donker". Kijk in de seriële monitor welk getal jij ziet
// bij licht en bij donker, en zet hier een getal tussenin.
const int DONKER_GRENS = 500;

Adafruit_NeoPixel ring(AANTAL_LEDS, RING_PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  Serial.begin(9600);
  ring.begin();
  ring.setBrightness(60);
  ring.show();
}

void loop() {
  int licht = analogRead(LICHT_PIN);   // Een getal van 0 tot 1023
  Serial.print(F("Lichtsensor: "));
  Serial.println(licht);

  // Bij deze sensor wordt het getal hoger als het donkerder wordt.
  // Werkt het bij jou net andersom? Draai dan > om naar <.
  bool donker = licht > DONKER_GRENS;

  for (int i = 0; i < AANTAL_LEDS; i++) {
    if (donker) {
      ring.setPixelColor(i, ring.Color(255, 140, 40));  // Warm geel licht
    } else {
      ring.setPixelColor(i, 0);                         // Uit
    }
  }
  ring.show();
  delay(200);
}