Ventilador inteligente

// Ventilador inteligente (termostato)
// ¿Hace demasiado calor? Entonces el relé se enciende, por ejemplo para un ventilador.
// En la pantalla ves la temperatura y si el ventilador está encendido.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT del DHT11 en pin 2
const int RELE_PIN = 7;       // S del relé en pin 7
const float ENCENDER_SOBRE = 25.0; // Sobre esta temperatura se enciende el ventilador
const float APAGAR_BAJO = 24.0; // Bajo esta temperatura se vuelve a apagar

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 pantalla(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool ventiladorEncendido = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELE_PIN, OUTPUT);
  digitalWrite(RELE_PIN, LOW);   // Empieza con el relé apagado
  dht.begin();
  pantalla.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  pantalla.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperatura = dht.readTemperature();

  if (!isnan(temperatura)) {
    // Dos límites, para que el relé no haga clic sin parar
    if (temperatura > ENCENDER_SOBRE) ventiladorEncendido = true;
    if (temperatura < APAGAR_BAJO) ventiladorEncendido = false;
    digitalWrite(RELE_PIN, ventiladorEncendido ? HIGH : LOW);
  }

  pantalla.clearDisplay();
  pantalla.setTextSize(2);
  pantalla.setCursor(0, 0);
  if (isnan(temperatura)) {
    pantalla.print(F("DHT11 ?"));
  } else {
    pantalla.print(temperatura, 1);
    pantalla.print((char)247);
    pantalla.print(F("C"));
  }
  pantalla.setTextSize(1);
  pantalla.setCursor(0, 22);
  pantalla.print(ventiladorEncendido ? F("Ventilador: SI") : F("Ventilador: no"));
  pantalla.display();

  Serial.print(F("Temperatura: "));
  Serial.print(temperatura);
  Serial.println(ventiladorEncendido ? F(" C  -> SI") : F(" C  -> no"));

  delay(2000);
}