Ventilateur malin

// Ventilateur malin (thermostat)
// Fait-il trop chaud ? Alors le relais s'allume, par exemple pour un ventilateur.
// Sur l'ecran, tu vois la temperature et si le ventilateur est allume.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT du DHT11 sur pin 2
const int RELAIS_PIN = 7;     // S du relais sur pin 7
const float MARCHE_AU_DESSUS = 25.0; // Au-dessus de cette temperature, le ventilateur s'allume
const float ARRET_EN_DESSOUS = 24.0; // Sous cette temperature, il s'eteint de nouveau

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 ecran(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool ventilateurAllume = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELAIS_PIN, OUTPUT);
  digitalWrite(RELAIS_PIN, LOW);   // Commence avec le relais eteint
  dht.begin();
  ecran.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  ecran.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperature = dht.readTemperature();

  if (!isnan(temperature)) {
    // Deux limites, pour que le relais ne clique pas sans arret
    if (temperature > MARCHE_AU_DESSUS) ventilateurAllume = true;
    if (temperature < ARRET_EN_DESSOUS) ventilateurAllume = false;
    digitalWrite(RELAIS_PIN, ventilateurAllume ? HIGH : LOW);
  }

  ecran.clearDisplay();
  ecran.setTextSize(2);
  ecran.setCursor(0, 0);
  if (isnan(temperature)) {
    ecran.print(F("DHT11 ?"));
  } else {
    ecran.print(temperature, 1);
    ecran.print((char)247);
    ecran.print(F("C"));
  }
  ecran.setTextSize(1);
  ecran.setCursor(0, 22);
  ecran.print(ventilateurAllume ? F("Ventilo: ON") : F("Ventilo: off"));
  ecran.display();

  Serial.print(F("Temperature: "));
  Serial.print(temperature);
  Serial.println(ventilateurAllume ? F(" C  -> ON") : F(" C  -> off"));

  delay(2000);
}