Deluxe parking sensor

// Deluxe parking sensor
// Just like the normal parking sensor, but now you also see the distance on the OLED screen.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG_PIN = 9;     // Trig of the HC-SR04 on pin 9
const int ECHO_PIN = 10;    // Echo of the HC-SR04 on pin 10
const int BUZZER_PIN = 8;   // S of the buzzer on pin 8

Adafruit_SSD1306 display(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

// Measure the distance in centimeters
long measureDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long time = pulseIn(ECHO_PIN, HIGH, 30000);
  if (time == 0) return 999;   // No echo: nothing nearby
  return time / 58;
}

// Put the distance big on the screen, with a little bar below it
void showDistance(long distance) {
  display.clearDisplay();
  display.setTextSize(2);
  display.setCursor(0, 0);
  if (distance >= 999) {
    display.print(F("---"));
  } else {
    display.print(distance);
    display.print(F(" cm"));
  }
  // Little bar: the closer, the longer
  int length = map(constrain(distance, 0, 100), 0, 100, 128, 0);
  display.fillRect(0, 24, length, 8, SSD1306_WHITE);
  display.display();
}

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  long distance = measureDistance();
  showDistance(distance);

  if (distance < 5) {
    digitalWrite(BUZZER_PIN, HIGH);   // Very close: one long tone
    delay(100);
  } else if (distance < 50) {
    digitalWrite(BUZZER_PIN, HIGH);   // Short beep
    delay(50);
    digitalWrite(BUZZER_PIN, LOW);
    delay(distance * 10);              // Closer = beeps faster
  } else {
    digitalWrite(BUZZER_PIN, LOW);
    delay(100);
  }
}