Smart fan

// Smart fan (thermostat)
// Is it getting too warm? Then the relay turns on, for example for a fan.
// On the screen you see the temperature and whether the fan is on.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;        // DAT of the DHT11 on pin 2
const int RELAY_PIN = 7;      // S of the relay on pin 7
const float ON_ABOVE = 25.0;  // Above this temperature the fan turns on
const float OFF_BELOW = 24.0; // Below this temperature it turns off again

DHT dht(DHT_PIN, DHT11);
Adafruit_SSD1306 display(128, 32, &Wire, -1);  // OLED: SDA = A4, SCL = A5

bool fanOn = false;

void setup() {
  Serial.begin(9600);
  pinMode(RELAY_PIN, OUTPUT);
  digitalWrite(RELAY_PIN, LOW);   // Start with the relay off
  dht.begin();
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperature = dht.readTemperature();

  if (!isnan(temperature)) {
    // Two limits, so the relay does not keep clicking on and off
    if (temperature > ON_ABOVE) fanOn = true;
    if (temperature < OFF_BELOW) fanOn = false;
    digitalWrite(RELAY_PIN, fanOn ? HIGH : LOW);
  }

  display.clearDisplay();
  display.setTextSize(2);
  display.setCursor(0, 0);
  if (isnan(temperature)) {
    display.print(F("DHT11 ?"));
  } else {
    display.print(temperature, 1);
    display.print((char)247);
    display.print(F("C"));
  }
  display.setTextSize(1);
  display.setCursor(0, 22);
  display.print(fanOn ? F("Fan: ON") : F("Fan: off"));
  display.display();

  Serial.print(F("Temperature: "));
  Serial.print(temperature);
  Serial.println(fanOn ? F(" C  -> ON") : F(" C  -> off"));

  delay(2000);
}