Automatic barrier

// Automatic barrier
// Is a car coming (something closer than 15 cm)? Then the buzzer beeps and the barrier opens.

#include <Servo.h>

const int TRIG_PIN = 9;       // Trig of the HC-SR04 on pin 9
const int ECHO_PIN = 10;      // Echo of the HC-SR04 on pin 10
const int SERVO_PIN = 5;      // Orange/yellow wire of the servo on pin 5
const int BUZZER_PIN = 8;     // S of the buzzer on pin 8
const int CLOSE_BY = 15;      // From this distance (cm), the barrier opens

const int CLOSED = 0;         // Angle when the barrier is closed
const int OPEN = 90;          // Angle when the barrier is open

Servo barrier;

long measureDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long time = pulseIn(ECHO_PIN, HIGH, 30000);
  if (time == 0) return 999;
  return time / 58;
}

void setup() {
  Serial.begin(9600);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  barrier.attach(SERVO_PIN);
  barrier.write(CLOSED);
}

void loop() {
  long distance = measureDistance();

  if (distance < CLOSE_BY) {
    Serial.println(F("Car seen! Barrier open."));
    digitalWrite(BUZZER_PIN, HIGH);   // Short beep
    delay(100);
    digitalWrite(BUZZER_PIN, LOW);

    barrier.write(OPEN);
    delay(1000);
    // Stay open while the car is still there
    while (measureDistance() < CLOSE_BY) {
      delay(200);
    }
    delay(2000);                      // Wait a bit more until the car is really gone
    barrier.write(CLOSED);
    Serial.println(F("Barrier closed."));
  }
  delay(100);
}