Mini weather station

// Mini weather station
// The DHT11 measures the temperature and the humidity. The little OLED screen shows it.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

const int DHT_PIN = 2;          // DAT of the DHT11 is on pin 2
DHT dht(DHT_PIN, DHT11);

Adafruit_SSD1306 display(128, 32, &Wire, -1);  // OLED of 128 x 32 pixels (SDA = A4, SCL = A5)

void setup() {
  Serial.begin(9600);
  dht.begin();
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // 0x3C is the address of the display
    Serial.println(F("Display not found. Check the SDA and SCL wires."));
    while (true);                                   // Stop: without a display it makes no sense
  }
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  float temperature = dht.readTemperature();  // In degrees Celsius
  float humidity = dht.readHumidity();           // In percent

  display.clearDisplay();
  display.setTextSize(2);
  display.setCursor(0, 0);

  if (isnan(temperature) || isnan(humidity)) {   // Did measuring not work?
    display.setTextSize(1);
    display.print(F("No DHT11 found"));
  } else {
    display.print(temperature, 1);
    display.print((char)247);                  // The degree sign
    display.println(F("C"));
    display.print(humidity, 0);
    display.print(F("% hum"));

    Serial.print(F("Temperature: "));
    Serial.print(temperature);
    Serial.print(F(" C  Hum: "));
    Serial.print(humidity);
    Serial.println(F(" %"));
  }

  display.display();   // Only now does everything really appear on the display
  delay(2000);        // The DHT11 can measure only once every 2 seconds
}