Parking sensor

// Parking sensor
// The closer you get to the sensor, the faster the buzzer beeps. Just like in a car!

const int TRIG_PIN = 9;     // Trig of the HC-SR04 on pin 9
const int ECHO_PIN = 10;    // Echo of the HC-SR04 on pin 10
const int BUZZER_PIN = 8;   // S of the buzzer on pin 8

void setup() {
  Serial.begin(9600);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
}

// Measure the distance in centimeters
long measureDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);     // Send a short sound (you cannot hear it)
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long duration = pulseIn(ECHO_PIN, HIGH, 30000);  // How long until the echo comes back?
  if (duration == 0) return 999;                   // No echo: nothing nearby
  return duration / 58;                            // Convert time to centimeters
}

void loop() {
  long distance = measureDistance();
  Serial.print(F("Distance: "));
  Serial.print(distance);
  Serial.println(F(" cm"));

  if (distance < 5) {
    digitalWrite(BUZZER_PIN, HIGH);   // Very close: one long tone
    delay(100);
  } else if (distance < 50) {
    digitalWrite(BUZZER_PIN, HIGH);   // Short beep
    delay(50);
    digitalWrite(BUZZER_PIN, LOW);
    delay(distance * 10);              // Closer = shorter pause = faster beeps
  } else {
    digitalWrite(BUZZER_PIN, LOW);    // Far away: quiet
    delay(100);
  }
}